add rreview

rreview-git/PKGBUILD

@@ -0,0 +1,48 @@
+pkgver=1.0.0.r14
+_name=rreview
+pkgname=$_name-git
+pkgrel=1
+pkgdesc="A tool for reviewing bhop and surf maps."
+arch=('x86_64')
+url="https://git.itzana.me/StrafesNET/remote-script-review"
+license=('MIT')
+makedepends=('cargo')
+source=("$pkgname::git+https://git.itzana.me/StrafesNET/remote-script-review")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$pkgname"
+
+	# Parse Cargo.toml to get version number
+	local version=$(grep -oP 'version\s*=\s*"\K[^"]+' Cargo.toml | head -n 1)
+
+	# Get git revision number
+	local revision=$(git rev-list --count HEAD)
+
+	# Combine version and revision to form PKGBUILD version string
+	echo "${version}.r${revision}"
+}
+
+prepare() {
+	cd $pkgname
+	export RUSTUP_TOOLCHAIN=stable
+	cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+	cd $pkgname
+	export RUSTUP_TOOLCHAIN=stable
+	export CARGO_TARGET_DIR=target
+	cargo build --frozen --release --all-features
+}
+
+check() {
+	cd $pkgname
+	export RUSTUP_TOOLCHAIN=stable
+	cargo test --frozen --all-features
+}
+
+package() {
+	cd $pkgname
+	install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$_name"
+}